code: 9ferno

ref: 1882e954b0a8bdca38eff596783be26ca466f944
dir: /appl/alphabet/abc/type.b/

implement Type, Abcmodule;
include "sys.m";
	sys: Sys;
include "draw.m";
include "sh.m";
include "alphabet/reports.m";
	reports: Reports;
	report: import reports;
include "alphabet.m";
include "alphabet/abc.m";
	abc: Abc;
	Value: import abc;

Type: module {};
types(): string
{
	return "AAss*";
}

init()
{
	sys = load Sys Sys->PATH;
	reports = checkload(load Reports Reports->PATH, Reports->PATH);
	abc = checkload(load Abc Abc->PATH, Abc->PATH);
	abc->init();
}

quit()
{
}

run(errorc: chan of string, nil: ref Reports->Report,
		nil: list of (int, list of ref Value),
		args: list of ref Value
	): ref Value
{
	av := (hd args);
	a := av.A().i.alphabet;
	for(args = tl args; args != nil; args = tl args){
		if((e := a->importtype((hd args).s().i)) != nil){
			report(errorc, "type: "+(hd args).s().i+": "+e);
			return nil;
		}
	}
	return av.dup();
}

checkload[T](m: T, path: string): T
{
	if(m != nil)
		return m;
	raise sys->sprint("fail:cannot load %s: %r", path);
}